Pushing HydroSequence · May 6, 08:56 AM

I recently added my edits/fixes to HydroSequence.as (of HydroTween) in the google repository. I changed only a few lines of code which results in a much more powerful class. HydroSequence extends GoASAP’s SequenceCA class. You would think that this means you could use HydroSequence just like you had been able to use SequenceCA, with the additional features that HydroSequence adds. Well, this wasn’t the case, but now it is. Before, HydroSequence instantiated it’s own SequenceCA instance, now it just references itself.

The Demo

I put together a demo to showcase this new “feature”, but things didn’t turn out exactly as expected. Now I’m left wondering if these are shortcomings in my demo implementation, or in GoASAP itself.

The idea is that every time you click a button, that button’s 2-second sequence is added to the end of the currently playing sequence, like a queue. If there is no currently playing sequence, the button’s sequence becomes the current sequence. Each sequence consists of two tweens (HydroTweens).

Experiment 1

Try clicking on one of the buttons fast. The result is pretty much what you’d expect, except for one thing: the sequence stutters as long as you keep tapping the button. After you stop tapping, it proceeds as expected.

Experiment 2

Now try clicking different buttons fast. Again, similar to the first experiment.

Experiment 3

Click a button, wait a second until the sequence is in the second tween, now click a different button. Donk! Wtf?

  1. package {
  2. import flash.display.*;
  3. import flash.events.*;
  4. import flash.filters.*;
  5. import flash.system.LoaderContext;
  6. import org.papervision3d.materials.MovieMaterial;
  7. import org.papervision3d.objects.primitives.Sphere;
  8. import org.papervision3d.view.BasicView;
  9. import org.papervision3d.view.layer.ViewportLayer;
  10. import com.adobe.webapis.flickr.*;
  11. import com.adobe.webapis.flickr.events.FlickrResultEvent;
  12. import flash.net.URLRequest;
  13. import flash.display.Loader;
  14. import thumbnail.UrlHelper;
  15. import org.goasap.PlayStates;
  16. import com.hydrotik.go.HydroSequence;
  17. import com.bumpslide.ui.GenericButton;
  18.  
  19. public class Main extends MovieClip {
  20. private static const API_KEY:String = "9943f1cd0c02696b42b9c7d14c2b7794";
  21. private var view:BasicView;
  22. private var _flickrService:FlickrService;
  23. private var sphere:Sphere;
  24. private var sphereVpl:ViewportLayer;
  25. private var loader:Loader;
  26. private var seq:HydroSequence = new HydroSequence();
  27.  
  28. public function Main() {
  29. addEventListener(Event.ADDED_TO_STAGE, addedToStage);
  30. }
  31.  
  32. private function addedToStage(e:Event = null) : void {
  33. view = new BasicView(0,0, true);
  34. addChild(view);
  35. view.startRendering();
  36.  
  37. photosSearch("", "New Orleans");
  38. }
  39.  
  40.  
  41. // search for flickr photos...
  42. public function photosSearch( user_id:String = "", query:String = "" ) : void {
  43. trace("photoSearch...");
  44. _flickrService = new FlickrService( API_KEY );
  45. _flickrService.addEventListener( FlickrResultEvent.PHOTOS_SEARCH, onResult_photosSearch );
  46. _flickrService.photos.search(user_id, "", "any", query, null, null, null, null,-1,"interestingness-desc" );
  47. }
  48.  
  49. private function onResult_photosSearch(event:FlickrResultEvent):void {
  50. _flickrService.removeEventListener( FlickrResultEvent.PHOTOS_SEARCH, onResult_photosSearch );
  51. var url:String = UrlHelper.getFlickrUrl( (event.data.photos as PagedPhotoList).photos[int(Math.random()*10)] as Photo );
  52.  
  53. trace("loading " + url);
  54.  
  55. loader = new Loader();
  56. var loaderContext:LoaderContext = new LoaderContext();
  57. loaderContext.checkPolicyFile = true;
  58. loader.load(new URLRequest(url), loaderContext);
  59. loader.contentLoaderInfo.addEventListener(Event.INIT, loaderComplete);
  60.  
  61. }
  62.  
  63. private function loaderComplete(e:Event = null):void {
  64. loader.contentLoaderInfo.removeEventListener(Event.INIT, loaderComplete);
  65.  
  66. // add loaded photo to sprite (sp)
  67. var sp:Sprite = new Sprite();
  68. sp.addChild(loader);
  69. loader = loader;
  70. loader.alpha = 1;
  71.  
  72. // create a sphere with sp for material
  73. sphere = new Sphere(new MovieMaterial(sp, true, true),200,16,12);
  74. sphereVpl = view.viewport.getChildLayer(sphere);
  75. sphereVpl.filters = [ new GlowFilter(0xffffff,1,26,26,0,3), new BlurFilter(0,0,3) ];
  76. view.scene.addChild(sphere);
  77.  
  78. // create interface
  79. addChild(new GenericButton(150, 20, 10, 10, "glow sequence", doGlow));
  80. addChild(new GenericButton(150, 20, 10, 30, "blur sequence", doBlur));
  81. addChild(new GenericButton(150, 20, 10, 50, "spin sequence", doSpin));
  82. addChild(new GenericButton(150, 20, 10, 70, "alpha sequence", doAlpha));
  83. addChild(new GenericButton(150, 20, 10, 100, "NEXT STEP", doSkipStep));
  84.  
  85. }
  86.  
  87. private function seqAddStep(s:HydroSequence):void {
  88. if (seq.currentStep && seq.currentStep.state == PlayStates.PLAYING) {
  89. trace(" ..addStep");
  90. seq.addStep( s );
  91. } else {
  92. seq = s;
  93. }
  94. seq.start();
  95. }
  96.  
  97. private function doGlow(e:Event=null):void {
  98. seqAddStep(
  99. new HydroSequence(
  100. { target: sphereVpl, Glow_strength: 20, duration: 1 } ,
  101. { target: sphereVpl, Glow_strength: 0, duration: 1 }
  102. )
  103. );
  104. }
  105.  
  106. private function doBlur(e:Event=null):void {
  107. seqAddStep(
  108. new HydroSequence(
  109. { target: sphereVpl, Blur_blurX: 20, Blur_blurY: 20, duration: 1 } ,
  110. { target: sphereVpl, Blur_blurX: 0, Blur_blurY: 0, duration: 1 }
  111. )
  112. );
  113. }
  114.  
  115. private function doSpin(e:Event=null):void {
  116. seqAddStep(
  117. new HydroSequence(
  118. { target: sphere, rotationY: 360, duration: 1 } ,
  119. { target: sphere, rotationY: 0, duration: 1 }
  120. )
  121. );
  122. }
  123.  
  124. private function doAlpha(e:Event=null):void {
  125. seqAddStep(
  126. new HydroSequence(
  127. { target: loader, alpha: 0.3, duration: 1 } ,
  128. { target: loader, alpha: 1, duration: 1 }
  129. )
  130. );
  131. }
  132.  
  133. private function doSkipStep(e:Event = null):void {
  134. if (seq.playIndex < seq.length) {
  135. trace("Skipping... current index:"+seq.playIndex );
  136. seq.skipTo(seq.playIndex + 1);
  137. }
  138. }
  139. }
  140. }

Full Source Code (added 05.10.09)

From now on most of my experiments will be available here:

junglegym at Google Code

The repository is setup so that Flex 3 SDK is the only additional thing you might need to download in order to compile any demo.

— Pickle

---

Comment

Textile Help